***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 21, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PJMBZ27V 1 2 3
.param
+vc0 = 1.082e-13	 vc1 = 3.116e-12	 vc2 = 7.063e-12		vc3 = 1.255e-1
+tc1 = 1.958e-2		 tc2 = 1.732e-2
d1 1 3 zener
g1 3 1 value = {(vc0+vc1*v(3,1)+vc2*exp(vc3*v(3,1)))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d2 2 3 zener
g2 3 2 value = {(vc0+vc1*v(3,2)+vc2*exp(vc3*v(3,2)))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
.model zener d
***** flag parameter *****
+level = 1                     
***** dc model parameter *****
+ is = 9.084e-16	   n = 1.007		  rs = 1.568e-1
+ibv = 1e-3		 nbv = 1		  bv = 27
+ikf = 1.413e-1
***** capacitance parameter *****
+cjo = 4.394e-11	   m = 3.410e-1		  vj = 6.611e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.115		 xti = 3
+trs1 = -1.187e-3	trs2 = -2.606e-6		
+tbv1 = 7.815e-4	tbv2 = 4.041e-7		tikf = 1e-3
.ends PJMBZ27V
*$
